sdk/samples/all in on code/Visual Studio 2008/VBEFEntityDataModel/One2Many/One2ManyClass.vb

   1 '****************************** Module Header ******************************'
   2 ' Module Name:    One2ManyClass.vb
   3 ' Project:        VBEFEntityDataModel
   4 ' Copyright (c) Microsoft Corporation.
   5 '
   6 ' This example illustrates how to dinsert, update and query the two entities
   7 ' with one to many association.
   8 '
   9 ' This source is subject to the Microsoft Public License.
  10 ' See http://www.microsoft.com/opensource/licenses.mspx#Ms-PL.
  11 ' All other rights reserved.
  12 '
  13 ' THIS CODE AND INFORMATION IS PROVIDED "AS IS" WITHOUT WARRANTY OF ANY KIND,
  14 ' EITHER EXPRESSED OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE IMPLIED
  15 ' WARRANTIES OF MERCHANTABILITY AND/OR FITNESS FOR A PARTICULAR PURPOSE.
  16 '***************************************************************************'
  17
  18 #Region "Imports directives"
  19 Imports System
  20 Imports System.Collections.Generic
  21 Imports System.Linq
  22 Imports System.Text
  23 #End Region
  24
  25
  26 Namespace VBEFEntityDataModel.One2Many
  27     Friend Class One2ManyClass
  28
  29         ' Test all the methods in One2ManyClass
  30         Public Shared Sub One2ManyTest()
  31             InsertDepartmentWithCourse()
  32
  33             InsertCourse()
  34
  35             UpdateCourse()
  36
  37             UpdateDepartment()
  38
  39         End Sub
  40
  41         ' Insert new department with new course
  42         Public Shared Sub InsertDepartmentWithCourse()
  43
  44             Using context As New EFO2MEntities()
  45
  46                 Dim department As New Department() With _
  47                 { _
  48                     .DepartmentID = 4, _
  49                     .Name = "Software Engineering" _
  50                 }
  51
  52                 Dim course As New Course() With _
  53                 { _
  54                     .CourseID = 2202, _
  55                     .Title = "ADO.NET" _
  56                 }
  57
  58                 department.Course.Add(course)
  59
  60                 context.AddToDepartment(department)
  61
  62                 Try
  63
  64                     Console.WriteLine("Inserting department {0} with course " _
  65                         + "{1}", department.Name, course.Title)
  66
  67                     context.SaveChanges()
  68
  69                     Query()
  70
  71                 Catch ex As Exception
  72                     Console.WriteLine(ex.Message)
  73                 End Try
  74             End Using
  75         End Sub
  76
  77
  78         ' Insert new course to existing department
  79         Public Shared Sub InsertCourse()
  80
  81             Using context As New EFO2MEntities()
  82                 Dim course As New Course() With _
  83                 { _
  84                     .CourseID = 2203, _
  85                     .Title = "Object Oriented Programming" _
  86                 }
  87
  88                 course.Department = (From p In context.Department _
  89                     Where p.DepartmentID = 7 _
  90                     Select p).First()
  91
  92                 context.AddToCourse(course)
  93
  94                 Try
  95
  96                     Console.WriteLine("Inserting course {0} to department " _
  97                         + "{1}", course.Title, course.Department.Name)
  98
  99                     context.SaveChanges()
 100
 101                     Query()
 102
 103                 Catch ex As Exception
 104                     Console.WriteLine(ex.Message)
 105                 End Try
 106             End Using
 107         End Sub
 108
 109
 110         ' Get all the departments with courses
 111         Public Shared Sub Query()
 112
 113             Using context As New EFO2MEntities()
 114
 115                 Dim query = From p In context.Department.Include("Course") _
 116                             Select p
 117
 118                 Console.WriteLine("Deparments with their courses:")
 119
 120                 For Each d As Department In query
 121
 122                     Console.WriteLine("{0} {1}", d.DepartmentID, d.Name)
 123
 124                     For Each c As Course In d.Course
 125
 126                         Console.WriteLine("  {0}", c.Title)
 127
 128                     Next
 129                 Next
 130
 131                 Console.WriteLine()
 132
 133             End Using
 134         End Sub
 135
 136
 137         ' Update one existing course
 138         Public Shared Sub UpdateCourse()
 139
 140             Using context As New EFO2MEntities()
 141
 142                 Dim course As New Course()
 143
 144                 course.CourseID = 2203
 145
 146                 context.AttachTo("Course", course)
 147
 148                 course.Title = "OOP"
 149
 150                 Try
 151
 152                     Console.WriteLine("Modifying Course 2203's Title to {0}", _
 153                         course.Title)
 154
 155                     context.SaveChanges()
 156
 157                     Query()
 158
 159                 Catch ex As Exception
 160                     Console.WriteLine(ex.Message)
 161                 End Try
 162             End Using
 163         End Sub
 164
 165
 166         ' Update one existing department
 167         Public Shared Sub UpdateDepartment()
 168
 169             Using context As New EFO2MEntities()
 170
 171                 Dim department As New Department()
 172
 173                 department.DepartmentID = 1
 174
 175                 context.AttachTo("Department", department)
 176
 177                 department.Name = "Computer Engineering"
 178
 179                 department.Course.Add(New Course() With _
 180                 { _
 181                     .CourseID = 2204, _
 182                     .Title = "Arithmetic" _
 183                 })
 184
 185                 Try
 186
 187                     Console.WriteLine("Modifying Department 1's Title to {0}" _
 188                        + ", and insert a new Course 2204 into the " + _
 189                        "Department 1", department.Name)
 190
 191                     context.SaveChanges()
 192
 193                     Query()
 194
 195                 Catch ex As Exception
 196                     Console.WriteLine(ex.Message)
 197                 End Try
 198             End Using
 199         End Sub
 200
 201     End Class
 202
 203 End Namespace